10 REM SLOTANT7 PROGRAM CALCULATES WAVEGUIDE ANTENNA DIMENSIONS
20 REM FOR RECTANGULAR WAVEGUIDE
30 REM VERSION 1.7 OF 23 MAY 2002
40 REM BASIC PROGRAM BY ED MUNN, W6OYJ
50 REM FROM ARTICLE BY STEPHEN BELL KB7TRZ IN WEST COAST VHF/UHF
60 REM CONFERENCE PROCEEDINGS CERRITOS CA MAY 1995, PAGE 13
70 REM MODIFIED BY W6OYJ TO SHOW ANY SLOT OVERLAP OF WG CENTERLINE
80 REM AND CALCULATE OVERALL ANTENNA LENGTH. ALSO INCLUDES ESTIMATED
90 REM GAIN FROM W1GHZ EXCEL PROGRAM AND MODIFIED SLOT WIDTH/LENGTH
100 REM BY ELLIOTT IN SAME PROGRAM IN W1GHZ ANTENNA BOOK
110 REM PROGRAM RUNS IN QBASIC, BASICA, OR GW BASIC
120 REM
130 KEY OFF: CLS
140 PI = 3.14159:VP=.97:REM WAVEGUIDE VELOCITY FACTOR
150 PRINT "SLOTANT7 CALCULATES SLOT DIMENSIONS FOR WAVEGUIDE ANTENNAS"
160 PRINT "WITH RECTANGULAR WG. FROM ARTICLE BY STEPHEN BELL, KB7TRZ"
170 PRINT "IN 1995 WEST COAST VHF/UHF CONFERENCE PROCEEDINGS."
180 PRINT "MODIFIED BY W6OYJ TO ALERT FOR SLOT OVERLAP OF WG CENTER"
190 PRINT "AND ADD OVERALL LENGTH, ESTIMATED GAIN, AND MODIFIED"
200 PRINT "SLOT WIDTHS/LENGTHS FROM W1GHZ ANTENNA BOOK PROGRAM"
210 PRINT "VERSION 1.7 OF 23 MAY 2002"
220 PRINT
230 PRINT "***WARNING-RECENT REPORTED POOR PERFORMANCE HAS OCCURRED WITH"
240 PRINT "ANTENNAS DESIGNED FOR 2304 AND 5760 MHZ WITH THIS AND SIMILAR"
250 PRINT "PROGRAMS, WHILE ANTENNAS FOR 10 AND 29 GHZ HAVE PERFORMED WELL."
260 PRINT "RECOMMEND USE LARGEST SIZE WG SUITABLE FOR DESIGN FREQ."
270 PRINT "SMALLER GUIDE EVEN THOUGH ABOVE CUTOFF MAY NOT WORK VERY WELL"
280 PRINT "WITH THE DIMENSIONS GIVEN IN THESE PROGRAMS."
290 PRINT:PRINT
300 PRINT "SLOTANT7 WAVEGUIDE SLOT ANTENNA DESIGN PROGRAM"
320 INPUT "ENTER NUMBER OF SLOTS DESIRED "; N
330 PRINT "THIS MEANS THERE ARE ";N/2;" SLOTS PER FACE."
340 INPUT "ENTER INTERNAL WIDE DIMENSION OF WAVEGUIDE IN INCHES "; A
350 INPUT "ENTER INTERNAL NARROW DIMENSION OF W.G. IN INCHES "; B
360 INPUT "ENTER DESIRED OPERATING FREQUENCY IN MHZ "; FO
370 FO = FO / 1000: REM CONVERT TO GHZ
380 PRINT
390 A = A * 25.4: B = B * 25.4:WC=2*A:FC=300/WC
400 PRINT "WG CUTOFF WAVELENGTH=";WC;" MM, FREQ =";FC*1000;" MHZ."
410 WO = 300 / FO: PRINT "FREE SPACE WAVELENGTH IS "; WO; " MM"
420 IF WO >= WC THEN PRINT "***ERROR*** WG TOO SMALL FOR CHOSEN FREQUENCY"
430 IF WO >= WC THEN END
440 WG = 1 / SQR(((1 / WO) ^ 2) - ((1 / WC) ^ 2))
450 PRINT "GUIDE WAVELENGTH IS "; WG; " MM OR "; WG / 25.4; " IN."
460 DB=10*LOG((N/2)*WG/WO)/LOG(10)
470 PRINT "ESTIMATED GAIN IS ";DB;" DB"
480 PRINT
490 G = 1 / N
500 G1 = 2.09 * (WG / WO) * (A / B) * COS(PI * WO / 2 / WG) ^ 2
510 Y = G / G1
520 AG = ATN(Y / SQR(1 - Y ^ 2))
530 X = (A / PI) * SQR(AG)
540 PRINT "SLOT OFFSET FROM WG CENTER =";X; " MM OR "; X / 25.4; " IN."
550 LS = VP*WO / 2:REM SLOT LENGTH
560 PRINT "SLOT LENGTH ="; LS; " MM OR "; LS / 25.4; " IN."
570 SS = WG / 2
580 PRINT "SLOT CNTR-CNTR SPACING ="; SS; " MM OR "; SS / 25.4; " IN."
590 WS = A*.0625/.9:REM WIDTH FROM ELLIOTT PART OF W1GHZ EXCEL PROGRAM
600 PRINT "APPROX SLOT WIDTH ="; WS; " MM OR "; WS / 25.4; " IN."
610 ES=X-(WS/2):REM EDGE OFFSET FROM CENTERLINE IN MM
620 TS=SS
630 PRINT "TOP SLOT HEADSPACE =";TS;" MM OR ";TS/25.4;" IN."
640 PRINT "HEADSPACE = DIST. FROM CENTER OF TOP SLOT TO WG END PLATE."
650 OL=((N/2)*SS+(LS/2))/25.4:REM OVERALL LENGTH
660 PRINT"OVERALL LENGTH FROM BOTTOM SLOT EDGE TO WG END =";OL;" IN."
670 IF ES >= 0 THEN PRINT:PRINT: GOTO 710
680 PRINT "***WARNING-SLOTS OVERLAP WG CENTER BY ";-ES;" MM."
690 PRINT "GAIN WILL SUFFER."
700 PRINT "RECOMMEND LARGER WG OR LESS SLOTS FOR THIS DESIGN FREQUENCY."
710 END